Favorites
Show All / Manage

You have no favorites.


Page 1 of 1
User avatar
Villager
Im just wondering what really is the BEST animation settings,
like the canvas size, the publish settings, Swivel export settings, stuff like that.
So, if any one does know any recommended settings for High Quality Animation, pls comment below.

From the person you were just talking to you,
Audz

User avatar
Monk
I do my anims in a medium resolution with 16:9 width to height ratio. The medium size helps me preview it in the timeline and as a swf, the ratio lets me upscale it flawlessly to 720p or 1080p once it's in Swivel. If you use small resolutions in flash all movement will be shaky and brushwork will have errors even when you upscale.

For flash resolution it depends what your computer's CPU can handle, I use 800x450 in Flash since it's 16:9 and my craptop can handle it. I also use a modified VCam which is adaptive to any ratio and allows upscaling, you can download it here if you have Flash CS6 or higher, or if you have CS3 or higher you can replace your current vcam by doing the following:
Go into the vcam symbol, find the frame with an "a" on it, press F9 to access the code, delete it all, and add this AS3 code. Should work instantly.
Code:
/**
 * VCam AS3 v1.01
 *
 * VCam based on original code by Sham Bhangal and Dave Dixon
 *
 * Dynamic Registration AS3 code based on work by Oscar Trelles, AS2 work by Darron Schall (www.darronschall.com)
 * and AS1 work by Robert Penner (www.robertpenner.com)
 *
 * Special Thanks to Josh Steele and Jeff Brenner
 *
 * @author Bryan Heisey
 * @version 1.01
 * @created 27-May-2008
 * **Modified by heartofthestorm.hyunsdojo.com 20 Sep. 2017 to give option to disable caching to bitmap for when you want to upscale the stage size with Swivel.
 * **Caching to bitmap makes the vcam capture a fixed-res image to make it play better in swf but zooming into the created image shows it as pixelly.
 * **The downside of disabling caching is you can no longer apply filters to the vcam, the upside is you can click on buttons and upscale into swivel.
 * **I have no idea what I'm doing but I haven't had issues, let me know if something breaks.
 * Requirements: Flash CS3+ & Actionscript 3
 */

var isCache:Boolean=false; //Change to true if you want to cache as bitmap and access

visible=false;
if(isCache){
   parent.cacheAsBitmap=true;
}

// Get stage width and height //////////////////////////////////////////////

var oldScaleMode:String=stage.scaleMode;
stage.scaleMode="exactFit";

var sW:Number=stage.stageWidth;
var sH:Number=stage.stageHeight;

stage.scaleMode=oldScaleMode;

// Get Vcam width and height ///////////////////////////////////////////////

var bounds_obj:Object=this.getBounds(this);
var camH:Number=bounds_obj.height;
var camW:Number=bounds_obj.width;

// Creat Point for dynamic registration point //////////////////////////////

var rp:Point=new Point(x,y);

addEventListener(Event.ENTER_FRAME,camControl);
addEventListener(Event.REMOVED_FROM_STAGE,reset);

// Create BitmapData ///////////////////////////////////////////////////////
if(isCache){
   var bmp:Bitmap;
   var myBitmapData:BitmapData=new BitmapData(sW,sH,true,0);
   bmp=new Bitmap(myBitmapData);
}
camControl();

if(isCache){
   stage.addChild(bmp);
}
function camControl(...event):void {

   if(isCache){
      parent.visible=true;
   }

   // Move the registration point to the vCams current position ///////////////
   rp.x=x;
   rp.y=y;

   // Gets the current scale of the vCam //////////////////////////////////////
   var h:Number=camH * scaleY;
   var w:Number=camW * scaleX;

   // Gets the stage to vCam scale ratio //////////////////////////////////////
   var _scaleY:Number=sH / h;
   var _scaleX:Number=sW / w;

   // Positions the parent ////////////////////////////////////////////////////
   x2=w / 2 * _scaleX;
   y2=h / 2 * _scaleY;

   scaleX2=_scaleX;
   scaleY2=_scaleY;

   rotation2=- rotation;
   if(isCache){
      // Draw bitmap of parent////////////////////////////////////////////////////
      myBitmapData.lock();
      myBitmapData.fillRect(myBitmapData.rect,0x00);
      myBitmapData.unlock();

      myBitmapData.draw(stage);

      // Apply vCam filters to bitmap ////////////////////////////////////////////
      bmp.filters=this.filters;
      bmp.transform.colorTransform=this.transform.colorTransform;

      parent.visible=false;
   }
}

addEventListener(Event.REMOVED_FROM_STAGE,reset);

function reset(e:Event):void {
   // Cleans up data for garbage collection ///////////////////////////////////
   removeEventListener(Event.ENTER_FRAME,camControl);
   removeEventListener(Event.REMOVED_FROM_STAGE,reset);

   if(isCache){
      stage.removeChild(bmp);
      myBitmapData.dispose();
      bmp=null;
   }
   // Resets parent properties ////////////////////////////////////////////////
   parent.scaleX=1;
   parent.scaleY=1;
   parent.x=0;
   parent.y=0;
   parent.rotation=0;
   parent.visible=true;
}
function set x2(value:Number):void {
   var p:Point=parent.parent.globalToLocal(parent.localToGlobal(rp));
   parent.x+= value - p.x;
}
function get x2():Number {
   var p:Point=parent.parent.globalToLocal(parent.localToGlobal(rp));
   return p.x;
}
function set y2(value:Number):void {
   var p:Point=parent.parent.globalToLocal(parent.localToGlobal(rp));
   parent.y+= value - p.y;
}
function get y2():Number {
   var p:Point=parent.parent.globalToLocal(parent.localToGlobal(rp));
   return p.y;
}
function get scaleX2():Number {
   return parent.scaleX;
}
function set scaleX2(value:Number):void {
   setProperty2("scaleX",value);
}

function get scaleY2():Number {
   return parent.scaleY;
}

function set scaleY2(value:Number):void {
   setProperty2("scaleY",value);
}

function get rotation2():Number {
   return parent.rotation;
}
function set rotation2(value:Number):void {
   setProperty2("rotation",value);
}

function setProperty2(prop:String,n:Number):void {
   var a:Point=parent.parent.globalToLocal(parent.localToGlobal(rp));

   parent[prop]=n;

   var b:Point=parent.parent.globalToLocal(parent.localToGlobal(rp));

   parent.x-= b.x - a.x;
   parent.y-= b.y - a.y;
}

In Publish Settings make sure you max your audio if going to swivel, or knock it down a couple pegs if sharing as swf. Never leave the "convert stereo to mono" box checked for various reasons. All other publish settings are self-explanatory and the defaults are good.


User avatar
Villager
thx :) I have a crappy pc too so maybe those stuff can come in handy

From the person you were just talking to you,
Audz

Page 1 of 1
Search for:

Oh dear. Looks like there was a problem.
You are using a browser that doesn't support the technology this website uses.

Don't fret. There are solutions.

Oh dear. Looks like there was a problem.
You are using a version of Internet Explorer that this site doesn't support.

Don't fret. There are solutions.